.版本 2
.支持库 iext2
.程序集 程序集1
.子程序 _启动子程序, 整数型, , 请在本子程序中放置易模块初始化代码
_临时子程序 () ' 在初始化代码执行完毕后调用测试代码
返回 (0) ' 可以根据您的需要返回任意数值
.子程序 _临时子程序
' 本名称子程序用作测试程序用,仅在开发及调试环境中有效,编译发布程序前将被系统自动清空,请将所有用作测试的临时代码放在本子程序中。 ***注意不要修改本子程序的名称、参数及返回值类型。
.子程序 加入信息, , 公开, 默认色:#白色;#红色;#橙色;#墨绿;#亮绿;#蓝色;#浅蓝;#紫色;#灰色;#浅灰;#棕色;#黑色。
.参数 超级编辑框, 超级编辑框
.参数 输出文本, 文本型, , 定义颜色段需要和本段定义的文本内容间有一个空格,例如“/#红色/ 这是一段红色文本/#蓝色/ 这是一段蓝色文本”;自定义颜色可直接用10进制色值
.局部变量 I, 整数型
.局部变量 处理输出信息, 文本型
.局部变量 分割文本1, 文本型, , "0"
.局部变量 分割文本2, 文本型, , "0"
.局部变量 是否加换行, 逻辑型
处理输出信息 = 子文本替换 (输出文本, “/#白色”, “/#” + 到文本 (#白色), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#红色”, “/#” + 到文本 (#红色), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#橙色”, “/#42495”, , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#黄色”, “/#” + 到文本 (#黄色), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#墨绿”, “/#” + 到文本 (#墨绿), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#亮绿”, “/#65280”, , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#蓝色”, “/#” + 到文本 (#蓝色), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#浅蓝”, “/#15509504”, , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#紫色”, “/#” + 到文本 (#紫色), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#灰色”, “/#” + 到文本 (#灰色), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#浅灰”, “/#” + 到文本 (#浅灰), , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#棕色”, “/#535921”, , , 真)
处理输出信息 = 子文本替换 (处理输出信息, “/#黑色”, “/#” + 到文本 (#黑色), , , 真)
分割文本1 = 分割文本 (处理输出信息, “/#”, )
是否加换行 = 假
.计次循环首 (取数组成员数 (分割文本1), I)
.如果真 (I ≠ 1)
分割文本2 = 分割文本 (分割文本1 [I], “/ ”, )
.如果真 (取数组成员数 (分割文本2) ≠ 2)
信息框 (“输出文本格式错误,请检查!!”, 0, , )
返回 ()
.如果真结束
.如果真 (取数组成员数 (分割文本1) = I)
是否加换行 = 真
.如果真结束
.如果 (文本是否数字 (分割文本2 [1]) = 假)
单次发送 (超级编辑框, 分割文本2 [2], #黑色, 是否加换行)
.否则
单次发送 (超级编辑框, 分割文本2 [2], 到数值 (分割文本2 [1]), 是否加换行)
.如果结束
.如果真结束
.计次循环尾 ()
.子程序 单次发送
.参数 超级编辑框, 超级编辑框
.参数 被加入的提示信息, 文本型
.参数 提示信息颜色, 整数型
.参数 是否加换行, 逻辑型
.局部变量 格式, 字符格式
超级编辑框.起始选择位置 = 超级编辑框.取文本长度 () - 1
格式.字体大小 = 9
格式.文本颜色 = 提示信息颜色
超级编辑框.置选择区字符格式 (格式)
.如果 (是否加换行 = 假)
超级编辑框.被选择文本 = 被加入的提示信息
.否则
超级编辑框.被选择文本 = 被加入的提示信息 + #换行符
.如果结束
超级编辑框.发送信息 (277, 7, 0)
.子程序 文本是否数字, 逻辑型
.参数 字符串, 文本型
.局部变量 Len, 整数型
.局部变量 i, 整数型
.局部变量 asc, 整数型
Len = 取文本长度 (字符串)
.如果真 (Len = 0)
返回 (假)
.如果真结束
.计次循环首 (Len, i)
asc = 取代码 (字符串, i)
.判断开始 (asc < 48) ' 0=48
返回 (假)
.判断 (asc > 57) ' 9=57
返回 (假)
.默认
.判断结束
.计次循环尾 ()
返回 (真)